35869.zip - BANEL100\ROUTINES.ASM

Current area: HOME ->
Zip File view

BANEL 100

This page allows you to view the contents of a file contained inside a ZIP archive available at Programmer's Heaven. This means you can view the code and find what you need from it without having to download the ZIP file first. If the file contains source code for a language we recognize, we have syntax highlighted it.

Filename displayed: BANEL100\ROUTINES.ASM
Found in file: 35869.zip

; version 3.0

get_nrm_mask: inc a
movc a,@a+pc
ret
db 1,2,4,8,10h,20h,40h,80h

get_nrm_cpl_mask:
inc a
movc a,@a+pc
ret
db 0feh,0fdh,0fbh,0f7h,0efh,0dfh,0bfh,7fh

get_rvs_mask: inc a
movc a,@a+pc
ret
db 80h,40h,20h,10h,8,4,2,1

get_rvs_cpl_mask:
inc a
movc a,@a+pc
ret
db 7fh,0bfh,0dfh,0efh,0f7h,0fbh,0fdh,0feh

hex_asc: anl a,#0fh
jnb acc.3,hex_asc_noadj
jb acc.2,hex_asc_adj
jnb acc.1,hex_asc_noadj
hex_asc_adj: add a,#'a'-'0'-10
hex_asc_noadj: add a,#'0'
ret

asc_hex: clr c
subb a,#'0'
jc asc_hex_no
subb a,#'9'-'0'+1
jc asc_hex_10
subb a,#'A'-'9'-1
jc asc_hex_no
subb a,#'F'-'A'+1
jc asc_hex_16
subb a,#'a'-'F'-1
jc asc_hex_no
subb a,#'f'-'a'+1
jnc asc_hex_ret
asc_hex_16: add a,#16
setb c
ret
asc_hex_10: add a,#10
setb c
asc_hex_ret: ret
asc_hex_no: clr c
ret

add_a_to_dptr: add a,dpl
mov dpl,a
clr a
addc a,dph
mov dph,a
ret

add_3a_to_dptr: mov b,a
rl a
add a,b
add a,dpl
mov dpl,a
clr a
addc a,dph
mov dph,a
ret

add_4a_to_dptr: rl a
rl a
add a,dpl
mov dpl,a
clr a
addc a,dph
mov dph,a
ret

inc_mod_b: inc a
cjne a,b,inc_skip
clr a
inc_skip: ret

dec_mod_b: jnz dec_skip
mov a,b
dec_skip: dec a
ret

hex_bcd: mov b,#10
div ab
swap a
add a,b
ret

bcd_hex: mov b,a
anl a,#0f0h
rr a
rr a
push acc
rr a
xch a,b
clr c
subb a,b
pop b
clr c
subb a,b
ret

; a=data dptr -> null-term xlat table
xlat_byte: mov b,a
sjmp xb_entry
xb_lp: inc dptr
inc dptr
xb_entry: clr a
movc a,@a+dptr
jz xb_ret
cjne a,b,xb_lp
inc dptr
clr a
movc a,@a+dptr
xb_ret: ret

adj_r0_r1: mov r2,a
clr c
subb a,r0
jc adjrr_lo
mov a,r1
clr c
subb a,r2
jc adjrr_hi
mov a,r2
ret
adjrr_hi: mov a,r1
ret
adjrr_lo: mov a,r0
ret

inc_r0_r1: xch a,r1
setb c
subb a,r1
jc incrr_lo
mov a,r1
inc a
ret
incrr_lo: mov a,r0
ret

dec_r0_r1: xch a,r0
clr c
subb a,r0
jnc decrr_lo
mov a,r0
dec a
ret
decrr_lo: mov a,r1
ret

IP2stats ActiveX 1.0 IP2stats ActiveX, Identify the country origins of your visitors in real time. -Display Country name, population, currency, and continent. -Redirect user based on country. -Web log stats and analys...	Snake 2.0 This Game is developed in C lang. Please try it and RATE the game	NetIPComboBox 1.2.0.0 The NetIPComboBox .Net Component is a combobox control designed for IP Address input. The NetIPComboBox allows/restricts the end user when entering an IP address. NetIPComboBox can be configured to ...

Zip File view

BANEL 100

Sponsored links